3k Associates Inc HP3000 FAQ TWiki TWiki > TWiki > HP3000FAQ > HP3000OperatingSystemQuestions > Hp3000JobGetSpoolfileNumber TWiki webs:
Main | TWiki | Sandbox
TWiki . { Welcome | Register | Changes | Topics | Index | Search | Go }

How can an HP3000 Job find its own $STDLIST Spoolfile Number (ofid)

Note; on MPE/iX 5.5 PP5 and later, all you have to do is reference the HPSPOOLID CI variable

--JeffVance?

The following command file, provided by JeffVance?, returns the spoolfile ID for the $STDLIST of whatever job or session you pass it (for earlier MPE/iX versions): 

PARM jobnum=!hplastjob, rtnvar=spid, entry=main
# (This command file assumes Express 3 release, if you are not on Express 3
# then change all '#' to 'comment' and change '!hplastjob' to ''.)
#
# This command file returns the spoolfile id (Onnnnnnn) in the CI variable
# named in the "rtnvar" parm. To reference this file you may need to
# append ".OUT.HPSPOOL" to the value in "rtn_parm". Example:
# :jobspid #J123 spid
# :print !!spid.out.hpspool
#
if '!entry' = 'main' then
# main entry, redirect output of :listspf
errclear
setvar !rtnvar ''
# could syntax check jobnum parm here...
listspf O@;seleq=[JOBNUM=!jobnum AND FILEDES=$stdlist] >./jobspid_tmp
if hpcierr <> 0 then
# listspf couldn't find job
echo !jobnum not found.
escape
else
xeq !hpfile !jobnum, !rtnvar, entry=parse_listspf <./jobspid_tmp
deletevar _jobspid_@
return
endif 
elseif '!entry' = 'parse_listspf' then
# listspf input has been redirected to TEMP file ./jobspid_tmp
# throw away 1st 3 lines.
input _jobspid_rec
input _jobspid_rec
input _jobspid_rec
setvar !rtnvar rtrim(str(input(),2,8))
return
endif

-- ChrisBartram - 18 May 2006



Topic Hp3000JobGetSpoolfileNumber . { Edit | Attach | Backlinks: Web All webs | Printable | History: r2 < r1 More }

Parents: Main > HP3000FAQ > HP3000OperatingSystemQuestions

This site is powered by the TWiki collaboration platformCopyright © by the contributing authors. All material on this collaboration platform is the property of the contributing authors.
Ideas, requests, problems regarding TWiki? Send feedback
Note: Please contribute updates to this topic on TWiki.org at TWiki:TWiki.Hp3000JobGetSpoolfileNumber